バッチファイルでファイル名に連続した数字をつける

バッチファイルを使ってファイル名に連番をつける方法をメモメモ…

たとえばテキストファイルが複数あるときに、それぞれのファイル名を MyText1.txt、MyText2.txt、MyText3.txt … のような連続した数字でリネームしたい場合の対処法です。もちろんファイル名だけではなくフォルダ名にも適用できます。

バッチファイルの作成方法

バッチファイルの作り方は簡単です。テキストドキュメントを新規作成し、適当なエディタ(メモ帳など)を使ってコマンドを書き、拡張子を .bat に変更して保存しなおすだけです。詳しい手順は前回の投稿で書いたので必要であれば参考にしてください。

コマンド

バッチファイルの内容はこんな感じです。

setlocal enabledelayedexpansion

set prefix=MyFile
set num=0

for %%F in (%*) do (
  set extention=%%~xF
  ren %%F !prefix!!num!!extention!
  set /a num+=1
)

endlocal

ファイルやフォルダをバッチファイル(.bat)上にドラッグ＆ドロップすると、自動的に MyFile0、MyFile1、MyFile2 …とリネームされるはずです。"MyFile" の部分を変更したい場合はset prefix=のうしろを好きな文字列に書き換えてください(スペースを含む場合はダブルクォーテーション " " でくくります)。開始番号を 0 からではなく別の数字にしたい場合はset num=のあとの数字を変更すればOKです。

ポイントとしてはやはり1行目のsetlocal enabledelayedexpansionでしょうか。バッチファイルではループ処理などでの変数を読み込むタイミングが他の言語とは異なります。そのため、7～9行目のループ内の処理がきちんと順番に実行されるように遅延環境変数の展開を有効化する必要があるというわけです。遅延環境変数については次のページの解説がわかりやすかったです。

バッチファイル界の魔境『遅延環境変数』に挑む（おまけもあるよ） - Qiita


注意点としては、多数のファイルを一度にD&Dした場合に、コマンドの文字数制限にひっかかってしまいうまく実行できない場合があるということです。そういう場合はディレクトリから直接ファイルを探して取得するようにしたほうがいいかもしれません。たとえば6行目の(%*)を(*.txt)と変更するとD&Dしたファイルではなく同一ディレクトリ内のすべてのテキストファイルを対象にできます。

それから、対象のファイルに特殊な文字列が含まれていた場合、そのファイル名自体がコマンドとして読み込まれてしまいエラーになることがあるそうです(参考ページ)。滅多に起きないとは思いますが一応書き留めておきます。

コマンド (ゼロ埋め)

ついでと言ってはなんですが、指定した桁数になるようにゼロ埋めする場合のコードも書いてみました。

setlocal enabledelayedexpansion

set prefix=MyFile
set pad=3
set num=0

for %%F in (%*) do (
  set padnum=00000000!num!
  set extention=%%~xF
  ren %%F !prefix!!padnum:~-%pad%!!extention!
  set /a num+=1
)

endlocal

数字の前にいくつかゼロをくっつけてから指定した桁数で切り取るという処理を行っています。桁数は4行目のset pad=で指定可能です。MyFile1 は MyFile001、MyFile10 は MyFille010 というように桁を揃えることができます。

おまけ　ゼロ埋め＆ファイル名の重複を避ける

コマンド (ゼロ埋め＆ファイル名の重複を避ける)

コメント欄でリクエストがあったので「同一ディレクトリにすでに同じ名前のファイルがあった場合は自動的に別の数字をつける」という機能も実装してみました。使い方はこれまで同様バッチファイル上にD&Dするだけです。

setlocal enabledelayedexpansion
 
set prefix=MyFile
set tempprefix=temp_
set pad=3
set num=0

for %%F in (%*) do (
  ren %%F "!tempprefix!%%~nxF"
)
for %%F in (%*) do (
  call :rename "%%~dpF!tempprefix!%%~nxF"
)
exit /b

:rename
  set file=%1
  set path=%~dp1
  set extention=%~x1
  :again
  set padnum=00000000!num!
  set newname=!prefix!!padnum:~-%pad%!!extention!

  if exist !path!!newname! (
    set /a num+=1
    goto again
  )

  ren !file! !newname!
  set /a num+=1
exit /b

endlocal

たとえば MyFile000 MyFile001 MyFile002 NewFile1 NewFile2 という5つのファイルが同じフォルダの中にあった場合、数字が重複しないように MyFile000 MyFile001 MyFile002 MyFile003 MyFile004 というふうにリネームします。別のフォルダに入ったファイルや拡張子の違うファイルだとうまく機能しないので注意。

技術的なポイントとしては

• もしも名前変更したいファイルの中にすでに名前変更後のものが含まれていた場合ややこしいことになるので、一旦ファイル名の先頭に適当な文字列をくっつけて別の名前にしておく(MyFile000 → temp_MyFile000)。文字列は既存のファイル名と重ならないようにset tempprefix=で指定。
• ファイル名が存在するかどうかのチェックは24行目のif existで行う。重複していればgotoで20行目まで戻って重複しなくなるまで数字を増やす。
• バッチファイルでは、forループ構文の中でgotoを使うとその時点でカウント変数%%Fが破棄されループも解除される仕様。実際の処理はcallを使ってサブルーチンとして呼び出す。

正直バッチファイルだけでここまで複雑な処理をしたことがないので、これで正解なのかはわかりません(もっとシンプルな方法があるかも…)。もしかしたら不具合が出る可能性もあるので確認しながら使ってください。

おまけ 2　フォルダ内のファイルをシャッフル

コマンド (フォルダ内のファイルをシャッフル)

コメント欄でリクエストがあった「フォルダ内のファイルをシャッフル(ランダムに並び替え)してその上で連番にリネームする」という処理です。好きなフォルダ(複数指定可)をバッチファイル上にD&Dすると、その中のすべてのファイルがリネームされます。

set prefix=MyFile
set startNum=0
set pad=3

for %%A in (%*) do (
  cd %%~fA
  setlocal enabledelayedexpansion

  @rem フォルダ内のすべてのファイルをランダムな数値でリネームする

  for %%B in (*) do (
    set extention=%%~xB
    ren "%%B" !random!!extention!
  )

  @rem フォルダ内のすべてのファイルを連番でリネームする

  set num=!startNum!
  for %%B in (*) do (
    set padnum=00000000!num!
    set extention=%%~xB
    ren "%%B" !prefix!!padnum:~-%pad%!!extention!
    set /a num+=1
  )

  endlocal
)

13行目では組み込み変数randomを使って0～32767の範囲の整数値を取得しています。なお、システム環境によってはループ処理が名前順に実行されず、うまく動作しない場合があるかもしれません。そのときは dir コマンドの /o:n オプションを利用するなどさらにひと手間必要になります。